/*  macros for  ImageJ 1.50 by Michael Cammer - please cite NYULMC Microscopy Core if data published
    Office of Collaborative Science, NYU Langone Medical Center & Skirball Institute
    Please cite NYULMC OCS Microscopy Core if data published using these methods  
    http://www.med.nyu.edu/ocs/microscopy/acknowledging-us
    Useful website for importing files directly from Zeiss:
    https://www.openmicroscopy.org/site/support/bio-formats5.1/users/imagej/

Macros for Lightsheet.Z1

v102 20151112
v107 adds subtraction of one channel from another
v109 fixes a problem so that hyperstacks remain hyperstacks with all slices and channels


*/

//==================================================================
var median = true;                          // change to false if don't want to median filter images
var compare = newArray(1 ,2 );    // The channels to compare, in this case green and blue
var tab = " \t ";                                 // For clean printout in cells or columns


/*==================================================================  
   This is a simple method to save all ROIs in the ROI Manager in the same directory/folder
   as the image.
   It does not take into account specific locations in hyperstacks (channels, z slices, frames, times, etc).
   It simply saves the ROI Manger as-is.
*/
macro "Save ROI Manager [F7]" {
   imageDir = getDirectory("image");                         // where to save results
   originalTitle = getTitleStripExtension(); 
   newName = imageDir + originalTitle + ".zip";
   roiManager("Save", newName);
}  // end Save ROI Manager


//=================================================
macro "Check Dimensions" {
   Stack.getDimensions(width, height, channels, slices, frames);
   print("\n", getTitle());
   print("channels: ", channels);
   print("slices (Z): ", slices);
   print("frames (T): ", frames);
   selectWindow("Log");
}  // end Check Dimensions


//=================================================
/*  This macro opens a series of .czi files, and does subtraction
*/
macro "Open images, process, and save results [q]" {
  requires("1.50");
printDateTime();
  run("Close All");
  openPath = getDirectory("Choose a Directory");
  fileList = getFileList(openPath);
  run("Colors...", "foreground=white background=black selection=cyan");
  filecount = 0;
  for (i=0; i<fileList.length; i++) {
    if ( (endsWith(fileList[i], ".czi")) || (endsWith(fileList[i], ".nd2" )) ) {                
      //open(openPath + fileList[i]);
      // run("Bio-Formats Importer", "open='" + openPath + fileList[i] + "' color_mode=Default view=[Hyperstack] stack_order=Default use_virtual_stack");
      print ("Currently opening/processing " + openPath + fileList[i] );
      selectWindow("Log");
      run("Bio-Formats Importer", "open='" + openPath + fileList[i] + "' color_mode=Default view=[Hyperstack] stack_order=Default ");

      title = getTitleStripExtension();
      original = getImageID();

      Stack.getDimensions(w, h, channels, slices, frames);
      slices = nSlices();
      run("Scale...", "x=0.5 y=0.5 z=1.0 width="+w+" height="+h+" depth="+slices+" interpolation=Bilinear average create title=rescaled");
      rename(title);
      rescaled = getImageID();
      selectImage(original);
      close();
      call("java.lang.System.gc");
      wait(1500);
      selectImage(rescaled);
           
      saveAs("Tiff", openPath + title +"_50percentXY" );   //  Save stack as TIF to save time later; opening from TIF faster than from CZI

      run("Subtract...", "value=200 stack");                                 // change value based on bg
      // ************  Or add flatfield correction of camera noise here ************

      //run("Z Project...", "projection=[Max Intensity]");
      //resetMinAndMax();
      //saveAs("Tiff", openPath + "MAX-" + title + filecount);
      //close();
      //selectImage(original); 
     
      // Do something else...
      

      selectImage(rescaled);
      close();
      // Clean up 
      call("java.lang.System.gc");
      wait(1500);
      call("java.lang.System.gc");
      wait(1500);

      filecount++;
    }  // if image opened
  }  // for i each fileList[]
printDateTime();
}  // end




//=================================================
/*  This macro splits channels and subtracts the green (C1) from the red (C2).
     Only the result is saved.
*/
macro "sub one channel from another, series off disk" {
  requires("1.50");
  printDateTime();
  run("Close All");
  openPath = getDirectory("Choose a Directory");
  fileList = getFileList(openPath);
  run("Colors...", "foreground=white background=black selection=cyan");
  filecount = 0;
  for (i=0; i<fileList.length; i++) {
    if ( endsWith(fileList[i], ".tif") ) {                
      print ("Currently opening/processing " + openPath + fileList[i] );
      selectWindow("Log");
      open(openPath + fileList[i]);

      title = getTitleStripExtension();
      rename(title);

      run("Split Channels");
      channel1 = "C2-" + title;
      channel2 = "C1-" + title;
      //imageCalculator("Difference create stack", channel1, channel2);
      imageCalculator("Subtract create stack", channel1, channel2);
      resetMinAndMax();
      saveAs("Tiff", openPath + title +"_RedMinusGreen" );    
                     
      run("Close All");
 
      call("java.lang.System.gc");
      wait(1500);
      call("java.lang.System.gc");
      wait(1500);
 
    }  // if image opened
  }  // for i each fileList[]
  printDateTime();
}  // end  subtract green from red




//===============================================================
macro "open crop project save" {
  requires("1.50");
  printDateTime();
  run("Close All");
  openPath = getDirectory("Choose a Directory");
  fileList = getFileList(openPath);
  run("Colors...", "foreground=white background=black selection=cyan");
  filecount = 0;
  for (i=0; i<fileList.length; i++) {
    if ( endsWith(fileList[i], ".tif") ) {                
      print ("Currently opening/processing " + openPath + fileList[i] );
      selectWindow("Log");
      open(openPath + fileList[i]);

      title = getTitleStripExtension();
      rename(title);

      makeRectangle(125, 0, 831, 629);
      run("Crop");
      run("3D Project...", "projection=[Brightest Point] axis=X-Axis slice=1 initial=140 total=1 rotation=10 lower=1 upper=255 opacity=0 surface=100 interior=50 interpolate");

      saveAs("Tiff", openPath + title +"_projection140" );    
                     
      run("Close All");
 
      call("java.lang.System.gc");
      wait(1500);
      call("java.lang.System.gc");
      wait(1500);
 
    }  // if image opened
  }  // for i each fileList[]
  printDateTime();
}  // end  "open crop project save"

















//===============================================================
// This macro demonstrates how to use the getDateAndTime() 
// function, available in ImageJ 1.34n or later.  Downloaded from IJ website.

function printDateTime() {
     MonthNames = newArray("Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec");
     DayNames = newArray("Sun", "Mon","Tue","Wed","Thu","Fri","Sat");
     getDateAndTime(year, month, dayOfWeek, dayOfMonth, hour, minute, second, msec);
     TimeString ="Date: "+DayNames[dayOfWeek]+" ";
     if (dayOfMonth<10) {TimeString = TimeString+"0";}
     TimeString = TimeString+dayOfMonth+"-"+MonthNames[month]+"-"+year+"   Time: ";
     if (hour<10) {TimeString = TimeString+"0";}
     TimeString = TimeString+hour+":";
     if (minute<10) {TimeString = TimeString+"0";}
     TimeString = TimeString+minute+":";
     if (second<10) {TimeString = TimeString+"0";}
     TimeString = TimeString+second;
     print(TimeString);
  }




/====================================
// Use this function to strip any number of extensions // off images.
// Returns the title without the extension.  Could be more elegant as an array, but this works.
//====================================
function getTitleStripExtension() {
  t = getTitle();
  t = replace(t, ".tif", "");        
  t = replace(t, ".tiff", "");       
  t = replace(t, ".lif", "");       
  t = replace(t, ".lsm", "");     
  t = replace(t, ".czi", "");      
  t = replace(t, ".nd2", "");    
  return t;
}