//=============================================================================
//  Modified 20140113 for single channel stacks.
//  Crop out the stack and then take the stacks and combine them.
//  calls function clipCellAndPopOnStack(original, clipstack);
//
macro "clip all ROIs in Roi Manager each as a stack [F4]" {
  if (Stack.isHyperstack) exit('Expecting a single channel stack.');
  if (nImages() > 1) exit('Only one stack should be open.');
  original = getImageID;
  // add command to get scale so that it may be restored before the final save.
  run("Set Scale...", "distance=1 known=1 pixel=1 unit=px");
  Stack.getDimensions(width, height, channels, slices, frames);
  Stack.getDisplayMode(displaymode);
  title = getTitle;
  bits = bitDepth();
  if (bits == 24) bitstring="RGB";
  else bitstring = ""+bits+"-bit";
  clipsize = getNumber("Enter side of square box in pixels: ", clipsize);
  clipstackID=newArray(roiManager("count"));    // The Image ID of each clipped stack will be stored here.
  clipstackTitle=newArray(roiManager("count"));    // The Image Title of each clipped stack will be stored here.
  
  run("Set Measurements...", "  centroid area redirect=None decimal=0");
  for (i=0;  i<roiManager("count");  i++){
      selectImage(original);
      roiManager("select", i);
      run("Measure");
      xc = getResult("X", nResults-1);
      yc = getResult("Y", nResults-1);
     selectImage(original);
     makeRectangle(xc-(clipsize/2), yc-(clipsize/2), clipsize, clipsize);
     run("Duplicate...", "title=["+title+i+"] duplicate range=1-20");
     clipstackID[i] = getImageID();
     clipstackTitle[i] = getTitle();
     run("Remove Overlay");
  }  // for  i
  selectWindow("Results");
  run("Close");
  selectImage(original);
  run("Close");
  combineStacks();
 

}  // macro "clip multiple ROIs in a stack and put in stack for montage"


//=======================================================================
function combineStacks() {

  // This is a finicky macro in that all windows have to be exactly the same size and 
  // type to work.
  // pass one
  // error check
  for (i=1; i<=nImages(); i++) {
    selectImage(i);
    if (i==1) {
      s = nSlices();
      x = getWidth();
      y = getHeight();
      type= bitDepth();
    } // if 

   if (s != nSlices()) exit("all windows must have same number of slices; "+getTitle()+" is different");
   if (x != getWidth()) exit("all windows must have same X; "+getTitle()+" is different");
   if (y != getHeight()) exit("all windows must have same Y; "+getTitle()+" is different");
   if (type != bitDepth()) exit("all windows must have same bit type; "+getTitle()+" is different");

   newName = getTitle() + i;
   rename(newName);  // fixes a problem if windows have the same title

 }  // for i in pass one

 
  //  Dialogue for the user to enter the montage #s.
  Dialog.create("Tiling");
  Dialog.addMessage("There are "+ nImages() + " to be combined.");
  Dialog.addNumber("Number of columns (across): ", 0); // add algorithm to factor & round up
  Dialog.addNumber("Number of rows (down): ", 0);
  Dialog.addChoice("Empty tiles should be: ", newArray("black", "white"));
  Dialog.show();
  //  Does not error check for integers.
  cols = Dialog.getNumber();
  rows = Dialog.getNumber();
  bgColor = Dialog.getChoice();

  // Make Dummy Stacks.
  if ((cols * rows) > nImages()) {
    n = nImages();    // nImages will change, so fixed here.
    for (i=0; i<((cols * rows)-n); i++)
      newImage("dummy"+i, "" + type + " " + bgColor, x, y, s);
  } // end if


  // get titles for combine() command
  n = nImages();
  titles = newArray(n);
  for(i=1; i<=n; i++) {
    selectImage(i);
    titles[i-1] = getTitle();
  }


  // Do the montage.
  t = 0;
  for (Y=0; Y<rows; Y++) {
    for(X=0; X<(cols-1); X++){
      t++;
      if(X==0) stack1=titles[t-1];
      else stack1 = "Combined Stacks";
      stack2 = titles[t];
      run("Combine...", "stack1=["+stack1+"] stack2=["+stack2+"]");
    } // for X
    t++;
    rename("Comb"+Y);  
    if (Y>0) run("Combine...", "stack1=Comb"+ (Y-1) + " stack2=Comb"+ Y + " combine");
    rename("Comb"+Y);
  } // for Y



}  // end combineStacks()
}

//=========================================================
macro "combineStacks" {
  combineStacks();
}

macro "make test stacks"{
  newImage("test", "8-bit ramp", 100, 100, 3);
  run("Rotate 90 Degrees Right");
  newImage("test", "8-bit ramp", 100, 100, 3);
  newImage("test", "8-bit white", 100, 100, 3);
  newImage("test", "8-bit black", 100, 100, 3);
}

// Modified 20121001 for composite color hyperstacks.
// The ROI of the cell is selected and the original image is active before this function is called.
//  clipstack contains the imageID of the clipped stacks window.
//=======================================================================
function clipCellAndPopOnStack(original, clipstack, chan) {
  requires("1.45m");
  run("Set Scale...", "distance=1 known=1 pixel=1 unit=px");
  run("Set Measurements...", "  centroid area redirect=None decimal=0");
  run("Measure");
  xc = getResult("X", nResults-1);
  yc = getResult("Y", nResults-1);
  selectWindow("Results");
  run("Close");
  selectImage(original);
  Stack.setChannel(chan);
  makeRectangle(xc-(clipsize/2), yc-(clipsize/2), clipsize, clipsize);
  run("Copy");
  run("Select None");
  setPasteMode("Copy");
  selectImage(clipstack);
  run("Paste");
  run("Add Slice");
}  // clip cell