/* This macro is a model for placing results of different categories and array lengths into a single table. */

macro "Make table of varying column lengths" {
	headings = newArray("Length", "Width", "Bestness");		// The categories of data.
	howManySamples = 4;
	randomDataBaseline = 10 + (10*random());
	Table.create("FUBAR table");
	for (i=0; i<howManySamples; i++) {
		howManyDataPoints = round(20 * random);
		results1 = newArray(howManyDataPoints);
		results2 = newArray(howManyDataPoints);
		results3 = newArray(howManyDataPoints);
		for (k=0; k<howManyDataPoints; k++) {
			results1[k] = randomDataBaseline + random();
			results2[k] = randomDataBaseline - random();
			results3[k] = randomDataBaseline * random();
		}
		Table.setColumn(headings[0] + IJ.pad(i,2), results1);
		Table.setColumn(headings[1] + IJ.pad(i,2), results2);
		Table.setColumn(headings[2] + IJ.pad(i,2), results3);
	}  // for how many samples
}

/*  This version puts each category into a different table.  */
macro "Make tables of different categories and varying column lengths" {
	headings = newArray("Length", "Width", "Bestness");		// The categories of data.
	for (i=0; i<headings.length; i++)
		Table.create(headings[i]);	
	howManySamples = 4;
	randomDataBaseline = 10 + (10*random());

	for (i=0; i<howManySamples; i++) {
		howManyDataPoints = round(20 * random);
		results1 = newArray(howManyDataPoints);
		results2 = newArray(howManyDataPoints);
		results3 = newArray(howManyDataPoints);
		for (k=0; k<howManyDataPoints; k++) {
			results1[k] = randomDataBaseline + random();
			results2[k] = randomDataBaseline - random();
			results3[k] = randomDataBaseline * random();
		}
		selectWindow(headings[0]);
		Table.setColumn(headings[0] + IJ.pad(i,2), results1);
		selectWindow(headings[1]);
		Table.setColumn(headings[1] + IJ.pad(i,2), results2);
		selectWindow(headings[2]);
		Table.setColumn(headings[2] + IJ.pad(i,2), results3);
	}  // for how many samples
}



macro "load macro [F4]" {
	//run("Install...", "install=[C:/Users/cammem01/OneDrive - NYU Langone Health/Holger_tables/tables example.ijm.ijm]");
	run("Install...", "install=[C:/Users/cammem01/OneDrive - NYU Langone Health/Holger_tables/tables example.ijm]");
}