//  Michael Cammer  20110428
//  macro for ImageJ

// This macro is a visual simulation only of microsclusters getting bigger at they move towards the center
// of a cell.
// It is for testing measurement macros.
// A real simulation would keep track of increased numbers of molecules.

//==========================================================
// macro for simulating csmac formation
macro "circle [q]" {
  run("Colors...", "foreground=cyan background=black selection=yellow");
  newImage("Untitled", "32-bit black", 128, 128, 1);

  xc = getWidth() / 2;
  yc = getHeight() / 2;
  step = 2 * 3.1415 / 6;
  ya =  getHeight() / 3;
  xa = ya;

  for (i=0; i<ya; i=i+4){
    drawCircle(xc, yc, xa-i, ya-i, step, 4 + i/4, i);
    run("Add Slice");
  }
  run("Delete Slice");


  run("Colors...", "foreground=black background=white selection=yellow");
  run("Select None");
  resetMinAndMax();
}

//====================================================
function drawCircle(xc, yc, xa, ya, step, base_spotsize, iteration){
  protein = iteration * 25;
  for (theta=0; theta<2*3.1415; theta = theta + step) {
    //xa = 10 * sin (theta);
    x = xc + xa * sin (theta);
    y = yc + ya * cos (theta);
    //putPixel(x,y,200);
   spotsize = base_spotsize + random()*3;
   makeOval(x, y, spotsize, spotsize);
   run("Add...", "value="+ protein +" slice");
   //run("Fill", "slice");                // change to add constant with a 32 bit image to make more like the real thing
  }
}  // function draw circle