/*  Next step is to save all 1st and 2nd shortest pairs with their distances.
     If distance greater than certain criteria, such as 15% longer than avg dist, then sever it.
     Then sort into clusters and do convex hull.

     Michael Cammer  20150707 for ImageJ 1.50a
*/

var shortestColor1 = "yellow";
var shortestColor2 = "ff8000";
var shortestColor3 = "0080ff";

macro "shortest and 2nd shortest [q]" {
    run("Select None");
  // This part of the macro gets the XY locations of the points.  It could
  //  be replaced with some other method such as opening a text file or measuring
  //  centroids of objects by some other method.
  run("Clear Results");
  run("Set Measurements...", "centroid redirect=None decimal=3");
  run("Find Maxima...", "noise=10 output=List");
  x = newArray(nResults());
  y = newArray(nResults());
  for(row=0; row<nResults(); row++) {
    x[row] = getResult("X", row);
    y[row] = getResult("Y", row);
  }  // for row to get XY locations

  //  calculate shortest and 2nd shortest
  run("Remove Overlay");
  dist = newArray(x.length);
  for(i=0; i<x.length; i++) {
    for(k=0; k<x.length; k++) {
        dist[k] =  sqrt(((y[i] - y[k]) * (y[i] - y[k])) + ((x[i] - x[k]) * (x[i] - x[k])));
    } // for k inside loop
    ranking = Array.rankPositions(dist);
    shortest1 = ranking[1];     //  ranking[0] will always give the position of 0 in the distance array
    shortest2 = ranking[2];
    shortest3 = ranking[3];

    // uncomment next three lines to show method
    // Array.print(dist);
    // Array.print(ranking);
    //  print("");

    makeLine(x[i],y[i], x[shortest1],y[shortest1], 1);
    Overlay.addSelection(shortestColor1);
    makeLine(x[i]+2,y[i]+2, x[shortest2]+2,y[shortest2]+2, 1);  // offset to help show when there are shortest & 2nd shortest
    Overlay.addSelection(shortestColor2);
    makeLine(x[i]-2,y[i]-2, x[shortest2]-2,y[shortest2]-2, 1);  // offset to help show when there are shortest & 2nd shortest
    Overlay.addSelection(shortestColor3);
  } // for i outside loop
  run("Select None");
} // end "shortest and 2nd shortest [q]"