//  Macros for applying the CLAHE plugin at http://rsb.info.nih.gov/ij/plugins/clahe/index.html
//  by Michael Cammer  March 2012




//===================================================================
//  This macro operates applies a few different CLAHE paramenters to the same image and pops the
//  results into a stack.   The paramenters are printed in the upper left of the image.  To turn this off, comment out the 
//  "drawString" line at the end of the loop.  On large images, beast run on a subset of the stack.  Then pick the
//   favorite result and run on the full image.
//===================================================================
macro "iterate through CLAHE options" {
  original = getImageID;
  blocksize = newArray(7, 15, 31, 63, 127, 512);
  contrast = newArray(3, 7, 11, 16);
  for (k=0; k<contrast.length; k++)
    for (i=0; i<blocksize.length; i++)  {
      selectImage(original);
      if (nSlices>1) setSlice(1);
      run("Select All");
      run("Copy");
      run("Add Slice");
      run("Paste");
      run("Select None");
      run("CLAHE ", "blocksize="+blocksize[i]+" histogram=256 maximum="+contrast[k]+"");
      drawString("blocksize "+blocksize[i]+", contrast "+contrast[k], 1, 30);
    }
}  // test CLAHE parameters
 

//===================================================================
//  Applies CLAHE to a stack of images.
//===================================================================
macro "CLAHE on a stack" {
  original = getImageID;
  Dialog.create("CLAHE on a stack");
  blocksize=127;   histogramsize=256;   maximum=3;
  Dialog.addNumber("Block size", blocksize);
  Dialog.addNumber("Histogram bins", histogramsize);
  Dialog.addNumber("Contrast max (3 to 12)", maximum);  // from 3 to 12
  Dialog.show();
  blocksize=Dialog.getNumber(); 
  histogramsize=Dialog.getNumber(); 
  maximum=Dialog.getNumber(); 
  for (i=1; i<=nSlices; i++) {
    selectImage(original);
    setSlice(i);
    run("CLAHE ", "blocksize="+blocksize+" histogram="+histogramsize+" maximum="+maximum+"");
  } // for i
  resetMinAndMax();
}  // CLAHE on a stack


//==================================================================
//  Applies CLAHE to all files in a directory.
//==================================================================
macro "run CLAHE on all files in a directory" {
  run("Input/Output...", "jpeg=100 gif=-1 file=.txt copy_row save_column save_row");
  path = getDirectory("Choose a Directory");
  filenames = getFileList(path);
  listArray(filenames);
  for (i=0; i<filenames.length; i++) {
    print("Trying to open ", path+filenames[i]);
    open(path+filenames[i]);
    win = getImageID;
    run("CLAHE ", "blocksize=63  histogram=1024 maximum=6");
    selectImage(win);
    saveAs("Jpeg", path+"CLAHE63-256-6_"+filenames[i]);
    selectImage(win);
    run("Close");
  } // for i
}

//==================================================================
//  Applies CLAHE to each channel in a HSV image.
//==================================================================
macro "run CLAHE in HSV mode" {
  run("HSB Stack");
  for (i=1; i<=3; i++){
    setSlice(i);
    run("CLAHE ", "blocksize=511 histogram=256 maximum=4");
  }  // for i
  run("RGB Color");
}

//==================================================================
function listArray (a) {
  for (i=0; i<a.length; i++)
    print(i, a[i]);
}