/*  Radial Plot macro for ImageJ for Chelsea Maniscalco by Michael Cammer  20150706


*/


var scaleFactor = 50;                         // how long to scale lines on graph
var wedgeAngle = 5 / 180 * PI / 2;    // in this example, wedge is 5 degrees wide
var outlineColor = "white";

macro "radial graph [f4]" {

  angles = newArray(85, 115,  83,  78,  90,    95, 15);                         //  in arrays for development; real data from text files
  dists    = newArray(  3,    4,   2.5,  1,    3.25,   2, 1.5);
  times   = newArray(  0,    0,    0,    1,     1,       2,   3);
  fillColors  = newArray("red", "magenta", "cyan", "green", "yellow");    // change from names to numbers

  newImage("plot", "RGB black", 512, 512, 1);
  xc = 256;
  yc = 256;
  setLineWidth(1);

  a = newArray(2);
  x = newArray(2);
  y = newArray(2);

  for (i=0; i<angles.length; i++) {
    angle = (angles[i] / 180) * PI;
    a[0] = angle-wedgeAngle;
    a[1] = angle+wedgeAngle;
    for (k=0; k<a.length; k++)  {
       x[k] = xc + dists[i] * sin(a[k]) * scaleFactor;
       y[k] = yc + dists[i] * cos(a[k]) * scaleFactor;
    }  // for k (makes the wedge)
       makePolygon(xc, yc, x[0], y[0], x[1], y[1]);
       run("Colors...", "foreground=" + fillColors[(times[i])] + " background=black selection=cyan");
       run("Fill", "slice");
       run("Colors...", "foreground=" + outlineColor + " background=black selection=cyan");
       run("Draw", "slice");

  }  // for i
  run("Select None");
}  // end macro