//  Macro to make particles moving in straight line with different
//  amounts of wiggle or speed variation.
//  For giving known quantities to particle tracking software to see how well features
//  are extracted and tracked.

//  Michael Cammer  circa 201111


// For these raw data we are imaging at 30 fps.


var boxsize = 512;


macro "simulation [q]" {
  setBatchMode(true);
  newImage("particle", "16-bit Black", boxsize, boxsize, 512);
  wiggle = 0;
  speedvariation = 0;
  for (y=20; y<getHeight(); y=y+30) {
    backup = speedvariation / 3;
    straightPathWithWiggle(y, 4, speedvariation, backup, wiggle, 2);
    wiggle++;
    speedvariation++;
  }  // for y
  setBatchMode(false);
  setSlice(1);
  resetMinAndMax();
}


//============================================================
// Moves a particle across the X axis.
// wiggle is the amount the particle may vary in Y per timepoint.
// speed is the number of pixels per timepoint.
// speedvariation is the amount the particle speed may vary per timepoint.
// backup is the allowable reversal in direction per timepoint.
//============================================================
function straightPathWithWiggle(starty, speed, speedvariation, backup, wiggle, particlesize) {
  x = 0;
  slice =1;
  while ((x < getWidth()) && (slice <= nSlices)) {
    setSlice(slice);
    slice++;
    y = starty + (wiggle * random());  // add a negative component to this
  
    drawParticle(x, y, 2, 4095, 2);
    x = x + speed + (speedvariation * (random()-0.5)) - (backup * random());
    
  }


}



//==========================================
function drawParticle(xc, yc, size, intensity, blur) {
  xcc = xc - (size/2);
  ycc = yc - (size/2);
  makeOval (xcc, ycc, size, size);
  run("Set...", "value=" + intensity + " slice");
  xcc = xc - (size/2) - blur*3;
  ycc = yc - (size/2) - blur*3;
  makeOval (xcc, ycc, size+blur*6, size+blur*6);
  run("Gaussian Blur...", "sigma="+blur+" slice");
  run("Select None");
}  // drawParticle