/*   
If macro used for publication of data please acknowledge NYULMC DART Microscopy Laboratory
v100 20170411  by Michael Cammer 


   Macro expects two windows open.
   1.  A single channel stack with XY images through time.  This window must be the active window.  (Other images may
         be open too.) 
   2.  ROI Manager window populated with ROIs to be intensity measured through time.
         To get ROIs quickly, we recommend making a maximum pixel projection through time.
         Then using threshold and magic wand tool to add cells that are not touching and manually tracing to
         add cells that are touching.

   Output is columns of tab delimitted numbers that may be saved as text file or copy and pasted into favorite spreadsheet
   program.

   In this version, bg subtraction would be of a constant.  Because ROIs may touch, difficult to 
   automate for a local bg subtraction, but could be implemented including bg calculated at each timepoint.

   If firing not coordinated, ImageJ does have the ability to find the peak timepoint intensity and align all the plots to this peak.

*/

var tab = " \t";

macro "make spreadsheet of intensity through time [F4]" {
  // could add error cecking here for valid image and ROImanager window
  t = getTitle;
  run("Set Measurements...", "mean redirect=None decimal=2");
  output = newArray(nSlices);  for (s=0; s<nSlices; s++) output[s] = "";
  
  for (i=0; i<roiManager("count"); i++) {
    run("Clear Results");
    roiManager("select", i);
    for (s=1; s<=nSlices; s++) {    // measure each slice
      setSlice(s);
      run("Measure");
      output[s-1] = output[s-1] + d2s(getResult("Mean", nResults-1), 2) + tab;
    }  // for each slice
  }  // for each region of interest
  print("\\Clear");
  print(t);
  for (s=0; s<nSlices; s++) 
    print(output[s]);
  

}