var tab = " \t ";


macro "Recolor and measure [q]" {
  images = nImages();
  for (i=1; i<=images; i++) {
    selectImage(i);
    recolorAndMeasure();
  }
}  // 




function recolorAndMeasure() {
  requires("1.50i");
  setBatchMode(true);
  original = getImageID();
  run("Remove Overlay");
  run("Select None");
  print( getTitle() );
  print("cell# \t intensity \t bg \t intensity-bg \t bodipy \t bg \t bodipy-bg");

  //  user enters these colors as needed
  colors = newArray("Green", "Red",  "Grays", "Grays");
  //  user enters title of channels as needed
  titles = newArray("DNA", "RedStuff", "GFP", "Far-Red","trans");

  Stack.getDimensions(width, height, channels, slices, frames);

  Stack.setDisplayMode("color");

  // This needs to be coded to have channels turned on or off
  Stack.setActiveChannels("1101000000");

  for (c=0; c<channels; c++) {
    Stack.setChannel(c+1);
    run(colors[c]);
  }
  run("Channels Tool...");
  selectImage(original);
  setSlice(2);  // redundant
  run("Duplicate...", "title=red channels=2");
  run("Median...", "radius=1");
  setAutoThreshold("Huang dark");
  setOption("BlackBackground", false);
  run("Convert to Mask");
  run("Dilate");
  run("Watershed");
  roiManager("Reset");
  run("Analyze Particles...", "size=10-Infinity circularity=0.25-1.00 exclude clear include add");
  selectWindow("red");
  close();
  selectImage(original);
  roiManager("Show all with labels");

  run("Set Measurements...", "mean redirect=None decimal=2");
  run("Clear Results");  // optional
  for (i=0; i< roiManager("count"); i++) {
    roiManager("select", i);
    Stack.setChannel(1);  //wait(100);
    run("Measure");
    crystalintensity = getResult("Mean", nResults()-1);
    run("Make Band...", "band=1");
    run("Measure");
    crystalbg = getResult("Mean", nResults()-1);
    roiManager("select", i);                  // There was a bug in the previous version fixed here.
    Stack.setChannel(2);  //wait(100);
    run("Measure");
    bintensity = getResult("Mean", nResults()-1);
    run("Make Band...", "band=1");
    run("Measure");
    bbg = getResult("Mean", nResults()-1);



    print ((i+1) + tab + crystalintensity + tab + crystalbg + tab + (crystalintensity - crystalbg) + tab + bintensity + tab + bbg + tab + (bintensity-bbg)    );
    //wait(200);
  }  // for  i
  setBatchMode(false);
  run("Select None");
  selectWindow("ROI Manager");
  run("Clear Results");
  selectWindow("Log");

}