/*  macros for  ImageJ 1.51 by Michael Cammer - please cite NYULMC Microscopy Core if data published
    Division of Advanced Research Technology & Skirball Institute https://med.nyu.edu/research/research-resources/scientific-cores-shared-resources/microscopy-laboratory/policies 

    These macros are for importing files saved as two separate channels where matching images end with:
     0 red
     1 green
Example:
MFGTMP-PC_170619130001_A01f00d0
MFGTMP-PC_170619130001_A01f00d1

v101 works for both TIF and TIFF extensions.

*/



//=================================================
/*  This macro opens a series of paired JPEG files and merges them.

     There must be an even  number of JPEG files in pairs in the directory for this macro to work.
     Best practices would error check.  THIS MACRO DOES NOT ERROR CHECK.
     If there is a stray JPEG file without a pairing, this macro will crash.    
     Files that don't have the JPEG extension are ignored.

*/
macro "Open images, process, and save results [q]" {
  run("Close All");
  openPath = getDirectory("Choose a Directory");
  fileList = getFileList(openPath);
  counter = 0;
  for (i=0; i<fileList.length; i++)          // first pass counts the number of files
    if ( endsWith(fileList[i], "TIF") || endsWith(fileList[i], "TIFF") ) counter++;
  jpgfilelist = newArray(counter);
  counter = 0;
  for (i=0; i<fileList.length; i++)          // second pass makes an array of only the  file names
    if  (endsWith(fileList[i], "TIF") || endsWith(fileList[i], "TIFF") ) {
       jpgfilelist[counter] = fileList[i];
      counter++;
    }  // if
  for (i=0; i<jpgfilelist.length; i=i+2) {
    open(openPath + jpgfilelist[i]);
    redtitle = getTitle;
    adjustRed ();
    open(openPath + jpgfilelist[i+1]);
    greentitle = getTitle;    
    adjustGreen ();
    newName = replace(greentitle, "1.TIF", "");       
    run("Merge Channels...", "c1="+redtitle+" c2="+greentitle+" create");
    saveAs("Tiff", openPath + newName);
    run("Close All");
  }
}  // Open images, process, and save results [q]



//=================================================
macro "test green contrast [F5]" {
  adjustGreen();
}

function adjustGreen () {
  run("Bandpass Filter...", "filter_large=200 filter_small=0 suppress=None tolerance=5");
  run("Set Measurements...", "mean standard display redirect=None decimal=4");
  run("Select None");
  run("Measure");
  bg = getResult("Mean", nResults-1) * 0.75;
  run("Subtract...", "value="+bg+"");
  run("Enhance Contrast...", "saturated=0");
  run("Apply LUT");
}

macro "test green contrast [F7]" {
  adjustRed();
}

function adjustRed () {
  run("Enhance Contrast", "saturated=0.2");
  run("Apply LUT");
}

















//====================================
// Use this function to strip any number of extensions // off images.
// Returns the title without the extension.  Could be more elegant as an array, but this works.
//====================================
function getTitleStripExtension() {
  t = getTitle();
  t = replace(t, ".tif", "");   
  t = replace(t, ".TIF", "");     
  t = replace(t, ".tiff", ""); 
  t = replace(t, ".TIFF", "");       
  t = replace(t, ".jpg", "");       
  t = replace(t, ".jpeg", "");     
  t = replace(t, ".czi", "");      
  t = replace(t, ".nd2", "");    
  return t;
}