//  Macro to open all LSM files in a directory, filter them, and save the filtered results in new
//  directories, one directory for each type of image processing.

//  This version 20130625 by M Cammer and J Muller.

//  ImageJ 1.47u

//  There may a few superfluous or redundant comands in here, but it works.


macro "Process files in directory" {
  print ("NEW RUN============================");  // debugging
  doMaxProject =true;
  path = getDirectory("Choose a Dir");
  filename = getFileList(path);
  newDir = path + "Max Projections" + File.separator; 
  newDirBkg = path + "Background Subtract" + File.separator; 
  if (File.exists(newDir))
          exit("Destination directory already exists(Max); remove it and then run this macro again"); 
  File.makeDirectory(newDir); 
  if (File.exists(newDirBkg))
          exit("Destination directory already exists (Bkg); remove it and then run this macro again"); 
  File.makeDirectory(newDirBkg); 
  for (i=0; i<filename.length; i++) {
            print("Current file is "+filename[i]);  // debugging
	if(endsWith(filename[i], ".lsm")) {
                        print("now processing "+ path+filename[i]);  // debugging
		open(path+filename[i]);
                        original = getImageID();
		title=getTitle();
                        Stack.getDimensions(width, height, channels, slices, frames);
                        run("Duplicate...", "title=[temp] duplicate channels=1-"+channels+" slices=1-"+slices);
                        filtered=getImageID();
		run("Median...", "radius=2 stack");  //                    CHANGE BACK TO 25 when working
		imageCalculator("Subtract create stack", title,"temp");
		saveAs("tiff", newDirBkg + title);                        
		
                        if (doMaxProject) {
                            selectImage(filtered);
                            run("Z Project...", "start=1 stop="+slices+" projection=[Max Intensity]");
                            saveAs("tiff", newDir + title);
                            close();
                        }  // maxProjection

                        // add addl functions here

                        selectImage(filtered);
		close(); 
                        selectImage(original);
                        close();
                        close();  // more cleanup
	}  // if endwith LSM
  } // for i
}  // end macro