//  ImageJ 1.48q3  
//  could be done with square or circular ROI
macro "local linear contrast enhance [q] " {
  t = getTitle();
  b = bitDepth();
  w = getWidth();
  h = getHeight();
  image = newArray(w *h);
  rmin = 31;
  rmax = 63 ;
     

  setBatchMode(true);       
  run("Duplicate...", "title=[tempabcdef]");  // to make batchmode work faster
  temp = getImageID();
  for (y=0; y<h; y++){
    showProgress(y/(h+1));
    for (x=0; x<w; x++) {
      r = rmin + (rmax-rmin) * random();
      i = (y*w) + x;
      image[i] = getPixel(x,y);
      makeOval(x-r, y-r, r*2, r*2);
      getRawStatistics(nPixels, mean, min, max, std, histogram);
      image[i] = image[i] - min;
      image[i] = image[i] * (255 / (max - min));
     }  // for x
  } // for y
  selectImage(temp);
  close();
  setBatchMode(false);

  newImage("min"+rmin+"max"+rmax+"_"+t, ""+32+"-bit black", w, h, 1);
  for (y=0; y<h; y++)
    for (x=0; x<w; x++) {
      putPixel(x,y, image[(y*w) + x] );
    }  // for x
  resetMinAndMax();
}  // end